update from main archive 960909
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strchr.s
1 /*
2  * Copyright (c) 1988 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 3. All advertising materials mentioning features or use of this software
14  *    must display the following acknowledgement:
15  *      This product includes software developed by the University of
16  *      California, Berkeley and its contributors.
17  * 4. Neither the name of the University nor the names of its contributors
18  *    may be used to endorse or promote products derived from this software
19  *    without specific prior written permission.
20  *
21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31  * SUCH DAMAGE.
32  */
33
34 #if defined(LIBC_SCCS) && !defined(lint)
35         .asciz "@(#)strchr.s    5.4 (Berkeley) 6/1/90"
36 #endif /* LIBC_SCCS and not lint */
37
38 /*
39  * Find the first occurence of c in the string cp.
40  * Return pointer to match or null pointer.
41  *
42  * char *
43  * strchr(cp, c)
44  *      char *cp, c;
45  */
46 #include "DEFS.h"
47
48         .lcomm  tbl,256
49
50 ENTRY(strchr, 0)
51         movzwl  $65535,r4       /* handy constant */
52         movq    4(ap),r1        /* r1 = cp; r2 = c */
53         movzbl  r2,r2
54         beql    Lzero           /* special case for c == '\0' */
55
56 /*
57  * Fancy scanc version.  Alas, it is not reentrant.
58  */
59         movab   tbl,r3          /* r3 = base of table */
60         bbss    $0,(r3),Lreent  /* ensure not reentering */
61         movab   (r3)[r2],r5     
62         incb    (r5)            /* mark both '\0' and c */
63 0:
64         scanc   r4,(r1),(r3),$1 /* look for c or '\0' */
65         beql    0b              /* still looking */
66         movl    r1,r0           /* return whatever we found */
67         tstb    (r0)
68         bneq    1f              #       unless it was '\0':
69         clrl    r0              #       then return NULL
70 1:
71         clrb    (r5)            /* clean up table */
72         clrb    (r3)
73         ret
74
75 /*
76  * Special case for \0.
77  */
78 Lzero:
79         locc    r2,r4,(r1)      /* just find end of string */
80         beql    Lzero           /* still looking */
81         movl    r1,r0           /* found it */
82         ret
83
84 /*
85  * Slower reentrant version is two two-step searches.  The first
86  * phase runs until we know where the string ends; it locates the
87  * first occurrence of c within a 65535-byte block.  If we find
88  * the end of the string first, we switch to the second phase,
89  * were we look only up to the known end of string.
90  */
91 Lreent:
92 0:      /* first phase */
93         movl    r1,r3
94         locc    $0,r4,(r3)      /* look for '\0' */
95         bneq    1f
96         locc    r2,r4,(r3)      /* look for c */
97         beql    0b              /* not found: reset pointer and loop */
98         movl    r1,r0           /* found: return it */
99         ret
100 1:      /* second phase */
101         subl3   r3,r1,r0        /* length of short block */
102         locc    r2,r0,(r3)      /* look for c */
103         beql    2f              /* not found: return NULL */
104         movl    r1,r0
105 2:      ret
106
107 weak_alias (strchr, index)