2004-10-15 Jakub Jelinek <jakub@redhat.com>
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strncmp.s
1 /*
2  * Copyright (c) 1983 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 4. Neither the name of the University nor the names of its contributors
14  *    may be used to endorse or promote products derived from this software
15  *    without specific prior written permission.
16  *
17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
27  * SUCH DAMAGE.
28  */
29
30 #if defined(LIBC_SCCS) && !defined(lint)
31         .asciz "@(#)strncmp.s   5.6 (Berkeley) 6/1/90"
32 #endif /* LIBC_SCCS and not lint */
33
34 /*
35  * Compare at most n characters of string
36  * s1 lexicographically to string s2.
37  * Return:
38  *      0       s1 == s2
39  *      > 0     s1 > s2
40  *      < 0     s2 < s2
41  *
42  * strncmp(s1, s2, n)
43  *      char *s1, *s2;
44  *      int n;
45  */
46 #include "DEFS.h"
47
48 ENTRY(strncmp, 0)
49         movl    4(ap),r1        # r1 = s1
50         movq    8(ap),r3        # r3 = s2; r4 = n
51 1:
52         clrl    r5              # calculate min bytes to next page boundary
53         subb3   r1,$255,r5      # r5 = (bytes - 1) to end of page for s1
54         subb3   r3,$255,r0      # r0 = (bytes - 1) to end of page for s2
55         cmpb    r0,r5           # r5 = min(r0, r5);
56         bgtru   2f
57         movb    r0,r5
58 2:
59         incl    r5              # r5 = min bytes to next page boundary
60         cmpl    r4,r5           # r5 = min(n, r5);
61         bgeq    3f
62         movl    r4,r5
63 3:
64         cmpc3   r5,(r1),(r3)    # compare strings
65         bneq    4f
66         subl2   r5,r4           # check for end of comparison
67         beql    5f
68         subl2   r5,r1           # check if found null yet
69         locc    $0,r5,(r1)
70         beql    1b              # not yet done, continue checking
71         subl2   r0,r3
72         mnegb   (r3),r0         # r0 = '\0' - *s2
73         cvtbl   r0,r0
74         ret
75 4:
76         subl2   r0,r5           # check for null in matching string
77         subl2   r5,r1
78         locc    $0,r5,(r1)
79         bneq    5f
80         subb3   (r3),(r1),r0    # r0 = *s1 - *s2
81         cvtbl   r0,r0
82         ret
83 5:
84         clrl    r0              # both the same to null
85         ret