Mon Jun 24 19:57:01 1996 Roland McGrath <roland@delasyd.gnu.ai.mit.edu>
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strncmp.s
1 /*
2  * Copyright (c) 1983 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 3. All advertising materials mentioning features or use of this software
14  *    must display the following acknowledgement:
15  *      This product includes software developed by the University of
16  *      California, Berkeley and its contributors.
17  * 4. Neither the name of the University nor the names of its contributors
18  *    may be used to endorse or promote products derived from this software
19  *    without specific prior written permission.
20  *
21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31  * SUCH DAMAGE.
32  */
33
34 #if defined(LIBC_SCCS) && !defined(lint)
35         .asciz "@(#)strncmp.s   5.6 (Berkeley) 6/1/90"
36 #endif /* LIBC_SCCS and not lint */
37
38 /*
39  * Compare at most n characters of string
40  * s1 lexicographically to string s2.
41  * Return:
42  *      0       s1 == s2
43  *      > 0     s1 > s2
44  *      < 0     s2 < s2
45  *
46  * strncmp(s1, s2, n)
47  *      char *s1, *s2;
48  *      int n;
49  */
50 #include "DEFS.h"
51
52 ENTRY(strncmp, 0)
53         movl    4(ap),r1        # r1 = s1
54         movq    8(ap),r3        # r3 = s2; r4 = n
55 1:
56         clrl    r5              # calculate min bytes to next page boundry
57         subb3   r1,$255,r5      # r5 = (bytes - 1) to end of page for s1
58         subb3   r3,$255,r0      # r0 = (bytes - 1) to end of page for s2
59         cmpb    r0,r5           # r5 = min(r0, r5);
60         bgtru   2f
61         movb    r0,r5
62 2:
63         incl    r5              # r5 = min bytes to next page boundry
64         cmpl    r4,r5           # r5 = min(n, r5);
65         bgeq    3f
66         movl    r4,r5
67 3:
68         cmpc3   r5,(r1),(r3)    # compare strings
69         bneq    4f
70         subl2   r5,r4           # check for end of comparison
71         beql    5f
72         subl2   r5,r1           # check if found null yet
73         locc    $0,r5,(r1)
74         beql    1b              # not yet done, continue checking
75         subl2   r0,r3
76         mnegb   (r3),r0         # r0 = '\0' - *s2
77         cvtbl   r0,r0
78         ret
79 4:
80         subl2   r0,r5           # check for null in matching string
81         subl2   r5,r1
82         locc    $0,r5,(r1)
83         bneq    5f
84         subb3   (r3),(r1),r0    # r0 = *s1 - *s2
85         cvtbl   r0,r0
86         ret
87 5:
88         clrl    r0              # both the same to null
89         ret