Fixed incorrect use of mvcle introduced by 2001-07-12 change.
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strncpy.s
1 /*
2  * Copyright (c) 1983 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 4. Neither the name of the University nor the names of its contributors
14  *    may be used to endorse or promote products derived from this software
15  *    without specific prior written permission.
16  *
17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
27  * SUCH DAMAGE.
28  */
29
30 #if defined(LIBC_SCCS) && !defined(lint)
31         .asciz "@(#)strncpy.s   5.6 (Berkeley) 6/1/90"
32 #endif /* LIBC_SCCS and not lint */
33
34 /*
35  * Copy string s2 over top of string s1.
36  * Truncate or null-pad to n bytes.
37  *
38  * char *
39  * strncpy(s1, s2, n)
40  *      char *s1, *s2;
41  */
42 #include "DEFS.h"
43
44 ENTRY(strncpy, R6)
45         movl    12(ap),r6       # r6 = n
46         bleq    done            # n <= 0
47         movl    4(ap),r3        # r3 = s1
48         movl    8(ap),r1        # r1 = s2
49 1:
50         movzwl  $65535,r2       # r2 = bytes in first chunk
51         cmpl    r6,r2           # r2 = min(bytes in chunk, n);
52         jgeq    2f
53         movl    r6,r2
54 2:
55         subl2   r2,r6           # update n
56         locc    $0,r2,(r1)      # '\0' found?
57         jneq    3f
58         subl2   r2,r1           # back up pointer updated by locc
59         movc3   r2,(r1),(r3)    # copy in next piece
60         tstl    r6              # run out of space?
61         jneq    1b
62         jbr     done
63 3:                              # copy up to '\0' logic
64         addl2   r0,r6           # r6 = number of null-pad bytes
65         subl2   r0,r2           # r2 = number of bytes to move
66         subl2   r2,r1           # back up pointer updated by locc
67         movc3   r2,(r1),(r3)    # copy in last piece
68 4:                              # null-pad logic
69         movzwl  $65535,r2       # r2 = bytes in first chunk
70         cmpl    r6,r2           # r2 = min(bytes in chunk, n);
71         jgeq    5f
72         movl    r6,r2
73 5:
74         subl2   r2,r6           # update n
75         movc5   $0,(r3),$0,r2,(r3)# pad with '\0's
76         tstl    r6              # finished padding?
77         jneq    4b
78 done:
79         movl    4(ap),r0        # return s1
80         ret