entered into RCS
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strncpy.s
1 /*
2  * Copyright (c) 1983 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 3. All advertising materials mentioning features or use of this software
14  *    must display the following acknowledgement:
15  *      This product includes software developed by the University of
16  *      California, Berkeley and its contributors.
17  * 4. Neither the name of the University nor the names of its contributors
18  *    may be used to endorse or promote products derived from this software
19  *    without specific prior written permission.
20  *
21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31  * SUCH DAMAGE.
32  */
33
34 #if defined(LIBC_SCCS) && !defined(lint)
35         .asciz "@(#)strncpy.s   5.6 (Berkeley) 6/1/90"
36 #endif /* LIBC_SCCS and not lint */
37
38 /*
39  * Copy string s2 over top of string s1.
40  * Truncate or null-pad to n bytes.
41  *
42  * char *
43  * strncpy(s1, s2, n)
44  *      char *s1, *s2;
45  */
46 #include "DEFS.h"
47
48 ENTRY(strncpy, R6)
49         movl    12(ap),r6       # r6 = n
50         bleq    done            # n <= 0
51         movl    4(ap),r3        # r3 = s1
52         movl    8(ap),r1        # r1 = s2
53 1:
54         movzwl  $65535,r2       # r2 = bytes in first chunk
55         cmpl    r6,r2           # r2 = min(bytes in chunk, n);
56         jgeq    2f
57         movl    r6,r2
58 2:
59         subl2   r2,r6           # update n
60         locc    $0,r2,(r1)      # '\0' found?
61         jneq    3f
62         subl2   r2,r1           # back up pointer updated by locc
63         movc3   r2,(r1),(r3)    # copy in next piece
64         tstl    r6              # run out of space?
65         jneq    1b
66         jbr     done
67 3:                              # copy up to '\0' logic
68         addl2   r0,r6           # r6 = number of null-pad bytes
69         subl2   r0,r2           # r2 = number of bytes to move
70         subl2   r2,r1           # back up pointer updated by locc
71         movc3   r2,(r1),(r3)    # copy in last piece
72 4:                              # null-pad logic
73         movzwl  $65535,r2       # r2 = bytes in first chunk
74         cmpl    r6,r2           # r2 = min(bytes in chunk, n);
75         jgeq    5f
76         movl    r6,r2
77 5:
78         subl2   r2,r6           # update n
79         movc5   $0,(r3),$0,r2,(r3)# pad with '\0's
80         tstl    r6              # finished padding?
81         jneq    4b
82 done:
83         movl    4(ap),r0        # return s1
84         ret