Converted to use weak aliases with macros from libc-symbols.h.
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strrchr.s
1 /*
2  * Copyright (c) 1988 Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 3. All advertising materials mentioning features or use of this software
14  *    must display the following acknowledgement:
15  *      This product includes software developed by the University of
16  *      California, Berkeley and its contributors.
17  * 4. Neither the name of the University nor the names of its contributors
18  *    may be used to endorse or promote products derived from this software
19  *    without specific prior written permission.
20  *
21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31  * SUCH DAMAGE.
32  */
33
34 #if defined(LIBC_SCCS) && !defined(lint)
35         .asciz "@(#)strrchr.s   5.4 (Berkeley) 6/1/90"
36 #endif /* LIBC_SCCS and not lint */
37
38 /*
39  * Find the last occurence of c in the string cp.
40  * Return pointer to match or null pointer.
41  *
42  * char *
43  * strrchr(cp, c)
44  *      char *cp, c;
45  */
46 #include "DEFS.h"
47
48         .lcomm  tbl,256
49
50 ENTRY(strrchr, 0)
51         movzwl  $65535,r4       /* handy 65535 */
52         movq    4(ap),r1        /* r1 = cp; r2 = c */
53         movzbl  r2,r2
54         beql    Lzero           /* special case for c == '\0' */
55
56         clrl    r5              /* r5 = pointer to last match */
57
58 /*
59  * Fancy scanc version.  Alas, it is not reentrant.
60  */
61         movab   tbl,r3          /* r3 = address of table */
62         bbss    $0,(r3),Lreent  /* ensure not reentering */
63         movab   (r3)[r2],r4
64         incb    (r4)            /* mark both '\0' and c */
65 0:
66         scanc   $65535,(r1),(r3),$1     /* look for c or '\0' */
67         beql    0b              /* keep looking */
68         tstb    (r1)
69         beql    1f              /* done if '\0' */
70         movab   (r1)+,r5        /* save most recently found, and skip over it */
71         jbr     0b              /* keep looking */
72 1:
73         movl    r5,r0           /* return last found (if any) */
74         clrb    (r4)            /* clean up table */
75         clrb    (r3)
76         ret
77
78 /*
79  * Special case for \0.
80  */
81 Lzero:
82         locc    $0,r4,(r1)      /* just find end of string */
83         beql    Lzero           /* still looking */
84         movl    r1,r0           /* found it */
85         ret
86
87 /*
88  * Slower reentrant version is two two-step searches.  The first
89  * phase runs until we know where the string ends; it locates any
90  * occurrences of c within a 65535-byte block.  Once we have found
91  * the end of the string, we find any further occurrences before
92  * that location.
93  */
94 Lreent:
95 0:      /* first phase */
96         movl    r1,r3
97         locc    $0,r4,(r3)      /* look for '\0' */
98         bneq    1f
99         locc    r2,r4,(r3)      /* continue phase 1 search for c */
100         beql    0b
101         movab   (r1)+,r5        /* found c: save and increment pointer */
102         brb     0b              /* and continue */
103
104 1:      /* second phase */
105         subl3   r3,r1,r0        /* length of short block */
106         movl    r3,r1
107 2:
108         locc    r2,r0,(r1)      /* look for c */
109         beql    3f              /* skip if not found */
110         movab   (r1)+,r5        /* save pointer as before */
111         sobgtr  r0,2b           /* adjust count and loop */
112 3:
113         movl    r5,r0           /* return stashed pointer */
114         ret