2004-10-15 Jakub Jelinek <jakub@redhat.com>
[kopensolaris-gnu/glibc.git] / sysdeps / vax / strsep.s
1 /*-
2  * Copyright (c) 1990 The Regents of the University of California.
3  * All rights reserved.
4  *
5  * Redistribution and use in source and binary forms, with or without
6  * modification, are permitted provided that the following conditions
7  * are met:
8  * 1. Redistributions of source code must retain the above copyright
9  *    notice, this list of conditions and the following disclaimer.
10  * 2. Redistributions in binary form must reproduce the above copyright
11  *    notice, this list of conditions and the following disclaimer in the
12  *    documentation and/or other materials provided with the distribution.
13  * 4. Neither the name of the University nor the names of its contributors
14  *    may be used to endorse or promote products derived from this software
15  *    without specific prior written permission.
16  *
17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
27  * SUCH DAMAGE.
28  */
29
30 #if defined(LIBC_SCCS) && !defined(lint)
31         .asciz "@(#)strsep.s    5.1 (Berkeley) 5/15/90"
32 #endif /* LIBC_SCCS and not lint */
33
34 /*
35  * Get next word from string *stringp, where words are
36  * strings separated by characters from delim.
37  *
38  * Writes NULs into the string at *stringp to end tokens.
39  * On return, *stringp points past the last NUL written (if there might
40  * be further tokens), or is NULL (if there are definitely no more tokens).
41  *
42  * If *stringp is NULL, strtoken returns NULL.
43  *
44  * char *
45  * strtoken(stringp, delim)
46  *      register char **stringp;
47  *      register char const *delim;
48  */
49 #include "DEFS.h"
50
51 ENTRY(strsep, 0)
52         tstl    *4(ap)          /* if (*stringp == NULL) */
53         bneq    0f
54         clrl    r0              #       return (NULL);
55         ret
56
57 0:
58         subl2   $32,sp          /* make room for 256 bit table */
59         movc5   $0,(sp),$0,$32,(sp)
60         movq    4(ap),r1        /* r1 = stringp, r2 = delim */
61
62         /* turn on bit for each character in s2, including '\0' */
63 1:
64         movzbl  (r2)+,r0
65         bbss    r0,(sp),1b
66         bneq    1b
67
68         movl    (r1),r3         /* r3 = s = *stringp */
69         movl    r3,r0           /* save return value */
70
71         /* scan for delimiters */
72 2:
73         movzbl  (r3)+,r2        /* c = *s++ */
74         bbc     r2,(sp),2b      /* loop until c is in table */
75         beql    3f
76         clrb    -1(r3)          /* if c!='\0', s[-1] = 0 */
77         movl    r3,(r1)         /* and *stringp = s */
78         ret
79 3:
80         clrl    (r1)            /* else *stringp = NULL */
81         ret