Complete rewrite.
[kopensolaris-gnu/glibc.git] / sysdeps / x86_64 / _mcount.S
1 /* Machine-specific calling sequence for `mcount' profiling function.  x86-64 version.
2    Copyright (C) 2002 Free Software Foundation, Inc.
3    Contributed by Andreas Jaeger <aj@suse.de>.
4    This file is part of the GNU C Library.
5
6    The GNU C Library is free software; you can redistribute it and/or
7    modify it under the terms of the GNU Lesser General Public
8    License as published by the Free Software Foundation; either
9    version 2.1 of the License, or (at your option) any later version.
10
11    The GNU C Library is distributed in the hope that it will be useful,
12    but WITHOUT ANY WARRANTY; without even the implied warranty of
13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
14    Lesser General Public License for more details.
15
16    You should have received a copy of the GNU Lesser General Public
17    License along with the GNU C Library; if not, write to the Free
18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19    02111-1307 USA.  */
20
21 /* Assembly stub to invoke _mcount().  Compiler generated code calls
22    this stub after executing a function's prologue and without saving any
23    registers.  It is therefore necessary to preserve %rcx, %rdx, %rsi, %rdi,
24    %r8, %r9 as they may contain function arguments.  */
25
26 #include <sysdep.h>
27
28         ASM_GLOBAL_DIRECTIVE C_SYMBOL_NAME(_mcount)
29         ASM_TYPE_DIRECTIVE(C_SYMBOL_NAME(_mcount), @function)
30         .align ALIGNARG(4)
31 C_LABEL(_mcount)
32         /* Allocate space for 7 registers.  */
33         subq    $56,%rsp
34         movq    %rax,(%rsp)
35         movq    %rcx,8(%rsp)
36         movq    %rdx,16(%rsp)
37         movq    %rsi,24(%rsp)
38         movq    %rdi,32(%rsp)
39         movq    %r8,40(%rsp)
40         movq    %r9,48(%rsp)
41
42         /* Setup parameter for __mcount_internal.  */
43         /* selfpc is the return address on the stack.  */
44         movq    56(%rsp),%rsi
45         /* Get frompc via the frame pointer.  */
46         movq    8(%rbp),%rdi
47 #ifdef PIC
48         call C_SYMBOL_NAME(__mcount_internal)@PLT
49 #else
50         call C_SYMBOL_NAME(__mcount_internal)
51 #endif
52         /* Pop the saved registers.  Please note that `mcount' has no
53            return value.  */
54         movq    48(%rsp),%r9
55         movq    40(%rsp),%r8
56         movq    32(%rsp),%rdi
57         movq    24(%rsp),%rsi
58         movq    16(%rsp),%rdx
59         movq    8(%rsp),%rcx
60         movq    (%rsp),%rax
61         addq    $56,%rsp
62         ret
63
64         ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
65
66 #undef mcount
67 weak_alias (_mcount, mcount)