Add libc_hidden_builtin_def.
[kopensolaris-gnu/glibc.git] / sysdeps / x86_64 / strcspn.S
1 /* strcspn (str, ss) -- Return the length of the initial segment of STR
2                         which contains no characters from SS.
3    For AMD x86-64.
4    Copyright (C) 1994-1997, 2000, 2002, 2003 Free Software Foundation, Inc.
5    This file is part of the GNU C Library.
6    Contributed by Ulrich Drepper <drepper@gnu.ai.mit.edu>.
7    Bug fixes by Alan Modra <Alan@SPRI.Levels.UniSA.Edu.Au>.
8    Adopted for x86-64 by Andreas Jaeger <aj@suse.de>.
9
10    The GNU C Library is free software; you can redistribute it and/or
11    modify it under the terms of the GNU Lesser General Public
12    License as published by the Free Software Foundation; either
13    version 2.1 of the License, or (at your option) any later version.
14
15    The GNU C Library is distributed in the hope that it will be useful,
16    but WITHOUT ANY WARRANTY; without even the implied warranty of
17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
18    Lesser General Public License for more details.
19
20    You should have received a copy of the GNU Lesser General Public
21    License along with the GNU C Library; if not, write to the Free
22    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
23    02111-1307 USA.  */
24
25 #include <sysdep.h>
26 #include "asm-syntax.h"
27
28 /* BEWARE: `#ifdef strcspn' means that strcspn is redefined as `strpbrk' */
29 #define STRPBRK_P (defined strcspn)
30
31         .text
32 ENTRY (strcspn)
33
34         movq %rdi, %rdx         /* Save SRC.  */
35
36         /* First we create a table with flags for all possible characters.
37            For the ASCII (7bit/8bit) or ISO-8859-X character sets which are
38            supported by the C string functions we have 256 characters.
39            Before inserting marks for the stop characters we clear the whole
40            table.  */
41         movq %rdi, %r8                  /* Save value.  */
42         subq $256, %rsp                 /* Make space for 256 bytes.  */
43         movq $32,  %rcx                 /* 32*8 bytes = 256 bytes.  */
44         movq %rsp, %rdi
45         xorq %rax, %rax                 /* We store 0s.  */
46         cld
47         rep
48         stosq
49
50         movq %rsi, %rax                 /* Setup skipset.  */
51
52 /* For understanding the following code remember that %rcx == 0 now.
53    Although all the following instruction only modify %cl we always
54    have a correct zero-extended 64-bit value in %rcx.  */
55
56         .p2align 4
57 L(2):   movb (%rax), %cl        /* get byte from skipset */
58         testb %cl, %cl          /* is NUL char? */
59         jz L(1)                 /* yes => start compare loop */
60         movb %cl, (%rsp,%rcx)   /* set corresponding byte in skipset table */
61
62         movb 1(%rax), %cl       /* get byte from skipset */
63         testb $0xff, %cl        /* is NUL char? */
64         jz L(1)                 /* yes => start compare loop */
65         movb %cl, (%rsp,%rcx)   /* set corresponding byte in skipset table */
66
67         movb 2(%rax), %cl       /* get byte from skipset */
68         testb $0xff, %cl        /* is NUL char? */
69         jz L(1)                 /* yes => start compare loop */
70         movb %cl, (%rsp,%rcx)   /* set corresponding byte in skipset table */
71
72         movb 3(%rax), %cl       /* get byte from skipset */
73         addq $4, %rax           /* increment skipset pointer */
74         movb %cl, (%rsp,%rcx)   /* set corresponding byte in skipset table */
75         testb $0xff, %cl        /* is NUL char? */
76         jnz L(2)                /* no => process next dword from skipset */
77
78 L(1):   leaq -4(%rdx), %rax     /* prepare loop */
79
80         /* We use a neat trick for the following loop.  Normally we would
81            have to test for two termination conditions
82            1. a character in the skipset was found
83            and
84            2. the end of the string was found
85            But as a sign that the character is in the skipset we store its
86            value in the table.  But the value of NUL is NUL so the loop
87            terminates for NUL in every case.  */
88
89         .p2align 4
90 L(3):   addq $4, %rax           /* adjust pointer for full loop round */
91
92         movb (%rax), %cl        /* get byte from string */
93         cmpb %cl, (%rsp,%rcx)   /* is it contained in skipset? */
94         je L(4)                 /* yes => return */
95
96         movb 1(%rax), %cl       /* get byte from string */
97         cmpb %cl, (%rsp,%rcx)   /* is it contained in skipset? */
98         je L(5)                 /* yes => return */
99
100         movb 2(%rax), %cl       /* get byte from string */
101         cmpb %cl, (%rsp,%rcx)   /* is it contained in skipset? */
102         jz L(6)                 /* yes => return */
103
104         movb 3(%rax), %cl       /* get byte from string */
105         cmpb %cl, (%rsp,%rcx)   /* is it contained in skipset? */
106         jne L(3)                /* no => start loop again */
107
108         incq %rax               /* adjust pointer */
109 L(6):   incq %rax
110 L(5):   incq %rax
111
112 L(4):   addq $256, %rsp         /* remove skipset */
113 #if STRPBRK_P
114         xorq %rdx,%rdx
115         orb %cl, %cl            /* was last character NUL? */
116         cmovzq %rdx, %rax       /* Yes: return NULL */
117 #else   
118         subq %rdx, %rax         /* we have to return the number of valid
119                                    characters, so compute distance to first
120                                    non-valid character */
121 #endif
122         ret
123 END (strcspn)
124 libc_hidden_builtin_def (strcspn)