Cancelable socket function implementation.
authordrepper <drepper>
Fri, 13 Dec 2002 10:52:58 +0000 (10:52 +0000)
committerdrepper <drepper>
Fri, 13 Dec 2002 10:52:58 +0000 (10:52 +0000)
nptl/sysdeps/unix/sysv/linux/i386/pt-socket.S [new file with mode: 0644]

diff --git a/nptl/sysdeps/unix/sysv/linux/i386/pt-socket.S b/nptl/sysdeps/unix/sysv/linux/i386/pt-socket.S
new file mode 100644 (file)
index 0000000..0b8523b
--- /dev/null
@@ -0,0 +1,80 @@
+/* Copyright (C) 1995, 1996, 1997, 1998, 2002 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <socketcall.h>
+
+#define P(a, b) P2(a, b)
+#define P2(a, b) a##b
+
+       .text
+/* The socket-oriented system calls are handled unusally in Linux.
+   They are all gated through the single `socketcall' system call number.
+   `socketcall' takes two arguments: the first is the subcode, specifying
+   which socket function is being called; and the second is a pointer to
+   the arguments to the specific function.
+
+   The .S files for the other calls just #define socket and #include this.  */
+
+#ifndef __socket
+# error "__socket and socket must be defined"
+#endif
+
+.globl __socket
+ENTRY (__socket)
+       /* We need one more register.  */
+       pushl %esi
+
+       /* Enable asynchronous cancellation.  */
+       call __libc_enable_asynccancel  /* No @plt */
+       movl %eax, %esi
+
+       /* Save registers.  */
+       movl %ebx, %edx
+
+       movl $SYS_ify(socketcall), %eax /* System call number in %eax.  */
+
+       /* Use ## so `socket' is a separate token that might be #define'd.  */
+       movl $P(SOCKOP_,socket), %ebx   /* Subcode is first arg to syscall.  */
+       lea 8(%esp), %ecx               /* Address of args is 2nd arg.  */
+
+        /* Do the system call trap.  */
+       int $0x80
+
+       /* Restore the cancellation.  */
+       xchgl %esi, %eax
+       call __libc_disable_asynccancel /* No @plt */
+
+       /* Restore registers.  */
+       movl %esi, %eax
+       movl %edx, %ebx
+       popl %esi
+
+       /* %eax is < 0 if there was an error.  */
+       cmpl $-125, %eax
+       jae SYSCALL_ERROR_LABEL
+
+       /* Successful; return the syscall's value.  */
+L(pseudo_end):
+       ret
+
+PSEUDO_END (__socket)
+
+#ifndef NO_WEAK_ALIAS
+weak_alias (__socket, socket)
+#endif