s390 specific files.
authoraj <aj>
Wed, 2 Aug 2000 14:17:30 +0000 (14:17 +0000)
committeraj <aj>
Wed, 2 Aug 2000 14:17:30 +0000 (14:17 +0000)
sysdeps/s390/elf/bsd-_setjmp.S [new file with mode: 0644]
sysdeps/s390/elf/bsd-setjmp.S [new file with mode: 0644]
sysdeps/s390/elf/setjmp.S [new file with mode: 0644]
sysdeps/s390/elf/start.S [new file with mode: 0644]

diff --git a/sysdeps/s390/elf/bsd-_setjmp.S b/sysdeps/s390/elf/bsd-_setjmp.S
new file mode 100644 (file)
index 0000000..1417270
--- /dev/null
@@ -0,0 +1 @@
+/* We don't need any code here since the setjmp.S file contains it.  */
diff --git a/sysdeps/s390/elf/bsd-setjmp.S b/sysdeps/s390/elf/bsd-setjmp.S
new file mode 100644 (file)
index 0000000..1417270
--- /dev/null
@@ -0,0 +1 @@
+/* We don't need any code here since the setjmp.S file contains it.  */
diff --git a/sysdeps/s390/elf/setjmp.S b/sysdeps/s390/elf/setjmp.S
new file mode 100644 (file)
index 0000000..952cba2
--- /dev/null
@@ -0,0 +1,58 @@
+/* setjmp for s390, ELF version.
+   Copyright (C) 2000 Free Software Foundation, Inc.
+   Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+#define _ASM
+#define _SETJMP_H
+#include <bits/setjmp.h>
+
+       /* We include the BSD entry points here as well but we make
+          them weak.  */
+ENTRY (setjmp)
+       .weak C_SYMBOL_NAME (setjmp)
+       lhi    %r3,1                /* second argument of one */
+       j      __sigsetjmp          /* branch relativ to __sigsetjmp */
+END (setjmp)
+
+       /* Binary compatibility entry point.  */
+ENTRY(_setjmp)
+       .weak  C_SYMBOL_NAME (_setjmp)
+ENTRY(__setjmp)
+       lhi    %r3,0                /* second argument of zero */
+
+ENTRY(__sigsetjmp)
+       stm    %r6,%r15,0(%r2)      /* store registers in jmp_buf */
+#ifdef PIC
+       /* We cannot use the PLT, because it requires that %r12 be set, but
+          we can't save and restore our caller's value.  Instead, we do an
+          indirect jump through the GOT. */
+       basr   %r1,0
+.L0:    al     %r1,.L1 - .L0(0,%r1) /* get address of global offset table */
+                                   /* get address of __sigjmp_save from got */
+       l      %r1,__sigjmp_save@GOT12(0,%r1)
+       br     %r1
+.L1:    .long  _GLOBAL_OFFSET_TABLE_ - .L0
+#else
+       basr   %r1,0
+.L0:    l      %r1,.L1-.L0(0,%r1)   /* load address of __sigjmp_save */
+       br     %r1                  /* tail-call __sigjmp_save */
+.L1:    .long  __sigjmp_save
+#endif
+END (__sigsetjmp)
diff --git a/sysdeps/s390/elf/start.S b/sysdeps/s390/elf/start.S
new file mode 100644 (file)
index 0000000..1455572
--- /dev/null
@@ -0,0 +1,95 @@
+/* Startup code compliant to the ELF s390 ABI.
+   Copyright (C) 2000 Free Software Foundation, Inc.
+   Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+/*
+   This is the canonical entry point, usually the first thing in the text
+   segment. Most registers' values are unspecified, except for:
+
+   %r14         Contains a function pointer to be registered with `atexit'.
+               This is how the dynamic linker arranges to have DT_FINI
+               functions called for shared libraries that have been loaded
+               before this code runs.
+
+   %r15                The stack contains the arguments and environment:
+               0(%r15)                 argc
+               4(%r15)                 argv[0]
+               ...
+               (4*argc)(%r15)          NULL
+               (4*(argc+1))(%r15)      envp[0]
+               ...
+                                       NULL
+*/
+
+       .text
+       .globl _start
+_start:
+       /* Setup pointer to literal pool of _start */
+       basr    %r13,0
+.L0:    ahi     %r13,.Llit-.L0
+
+       /* load argc and argv from stack */
+       la      %r4,4(%r15)             # get argv
+       l       %r3,0(%r15)             # get argc
+
+       /* align the stack to a double word boundary */
+       lhi     %r0,-8
+       nr      %r15,%r0
+
+       /* Setup a stack frame and a parameter area */
+       ahi     %r15,-104               # make room on stack
+       xc      0(4,%r15),0(%r15)       # clear back-chain
+
+       /* set up arguments for __libc_start_main:
+          main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
+          Note that envp will be determined later in __libc_start_main
+        */
+       stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
+       la      %r7,96(%r15)
+       l       %r6,.L2-.Llit(%r13)     # load pointer to _fini
+       l       %r5,.L1-.Llit(%r13)     # load pointer to _init
+       l       %r2,.L3-.Llit(%r13)     # load pointer to main
+
+       /* ok, now branch to the libc main routine */
+       l       %r1,.L4-.Llit(%r13)
+       basr    %r14,%r1
+
+       /* crash if __libc_start_main returns */
+       .word   0
+
+.Llit:
+.L1:    .long  _init
+.L2:    .long  _fini
+.L3:    .long  main
+.L4:    .long  __libc_start_main
+
+/* FIXME: FPU flags or what ?!? */
+
+       .section .rodata
+       .globl _fp_hw
+       .long 3
+       .size _fp_hw, 4
+
+/* Define a symbol for the first piece of initialized data.  */
+       .data
+       .globl __data_start
+__data_start:
+       .long 0
+       .weak data_start
+       data_start = __data_start