pthread_rwlock_rdlock on Linux/SH.
authordrepper <drepper>
Mon, 10 Feb 2003 09:19:25 +0000 (09:19 +0000)
committerdrepper <drepper>
Mon, 10 Feb 2003 09:19:25 +0000 (09:19 +0000)
nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_rdlock.S [new file with mode: 0644]

diff --git a/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_rdlock.S b/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_rdlock.S
new file mode 100644 (file)
index 0000000..2c6adf8
--- /dev/null
@@ -0,0 +1,220 @@
+/* Copyright (C) 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <lowlevelrwlock.h>
+#include <tcb-offsets.h>
+#include "lowlevel-atomic.h"
+
+#define SYS_futex              240
+#define FUTEX_WAIT             0
+#define FUTEX_WAKE             1
+
+#define EAGAIN         11
+#define EDEADLK                35
+
+
+       .text
+
+       .globl  __pthread_rwlock_rdlock
+       .type   __pthread_rwlock_rdlock,@function
+       .align  5
+__pthread_rwlock_rdlock:
+       mov.l   r12, @-r15
+       mov.l   r8, @-r15
+       sts.l   pr, @-r15
+       mov     r4, r8
+
+       /* Get the lock.  */
+       mov     #1, r3
+#if MUTEX == 0
+       XADD    (r3, @r4, r2)
+#else
+       XADD    (r3, @(MUTEX,r4), r2)
+#endif
+       tst     r2, r2
+       bf      1f
+2:
+       mov.l   @(WRITER,r8), r0
+       tst     r0, r0
+       bf      14f
+       mov.l   @(WRITERS_QUEUED,r8), r0
+       tst     r0, r0
+       bt      5f
+       mov.l   @(FLAGS,r8), r0
+       tst     r0, r0
+       bt      5f
+3:
+       mov.l   @(READERS_QUEUED,r8), r0
+       add     #1, r0
+       mov.l   r0, @(READERS_QUEUED,r8)
+       tst     r0, r0
+       bt      4f
+
+#if MUTEX == 0
+       DEC (@r8, r2)
+#else
+       DEC (@(MUTEX,r8), r2)
+#endif
+       tst     r2, r2
+       bf      10f
+11:
+       mov     r8, r4
+       add     #READERS_WAKEUP, r4
+       mov     #FUTEX_WAIT, r5
+       mov     #0, r6
+       mov     #SYS_futex, r3
+       extu.b  r3, r3
+       trapa   #0x14
+       SYSCALL_INST_PAD
+
+       /* Reget the lock.  */
+       mov     #1, r3
+#if MUTEX == 0
+       XADD    (r3, @r4, r2)
+#else
+       XADD    (r3, @(MUTEX,r4), r2)
+#endif
+       tst     r2, r2
+       bf      12f
+13:
+       mov.l   @(READERS_QUEUED,r8), r0
+       add     #-1, r0
+       mov.l   r0, @(READERS_QUEUED,r8)
+       tst     r0, r0
+       bf      2b
+       bra     2b
+        mov.l  r0, @(READERS_WAKEUP,r8)
+
+5:
+       mov     #0, r3
+       mov.l   @(NR_READERS,r8), r0
+       add     #1, r0
+       mov.l   r0, @(NR_READERS,r8)
+       tst     r0, r0
+       bt      8f
+
+9:
+#if MUTEX == 0
+       DEC (@r8, r2)
+#else
+       DEC (@(MUTEX,r8), r2)
+#endif
+       tst     r2, r2
+       bf      6f
+7:
+       lds.l   @r15+, pr
+       mov.l   @r15+, r8
+       mov.l   @r15+, r12
+       rts
+        mov    r3, r0
+
+1:
+       mov     r8, r5
+#if MUTEX != 0
+       add     #MUTEX, r5
+#endif
+       mov     r2, r4
+       mov.l   .Lwait0, r1
+       bsrf    r1
+        nop
+.Lwait0b:
+       bra     2b
+        nop
+14:
+       stc     gbr, r1
+       mov.w   .Ltcboff,r2
+       sub     r2,r1
+       mov.l   @(8,r1),r1
+       cmp/eq  r1, r0
+       bf      3b
+       /* Deadlock detected.  */
+       bra     9b
+        mov    #EDEADLK, r3
+
+6:
+       mov     r8, r4
+#if MUTEX != 0
+       add     #MUTEX, r4
+#endif
+       mov.l   .Lwake0, r1
+       bsrf    r1
+        nop
+.Lwake0b:
+       bra     7b
+        mov    #0, r3
+
+8:
+       /* Overflow.  */
+       mov.l   @(NR_READERS,r8), r1
+       add     #-1, r1
+       mov.l   r1, @(NR_READERS,r8)
+       bra     9b
+        mov    #EAGAIN, r3
+
+4:
+       /* Overflow.  */
+       mov.l   @(READERS_QUEUED,r8), r1
+       add     #-1, r1
+       mov.l   r1, @(READERS_QUEUED,r8)
+       bra     9b
+        mov    #EAGAIN, r3
+
+10:
+       mov     r8, r4
+#if MUTEX != 0
+       add     #MUTEX, r4
+#endif
+       mov.l   .Lwake1, r1
+       bsrf    r1
+        nop
+.Lwake1b:
+       bra     11b
+        nop
+
+12:
+       mov     r8, r5
+#if MUTEX != 0
+       add     #MUTEX, r5
+#endif
+       mov     r2, r4
+       mov.l   .Lwait1, r1
+       bsrf    r1
+        nop
+.Lwait1b:
+       bra     13b
+        nop
+
+.Ltcboff:
+       .word   TLS_PRE_TCB_SIZE
+       .align  2
+.Lwait0:
+       .long   __lll_mutex_lock_wait-.Lwait0b
+.Lwake0:
+       .long   __lll_mutex_unlock_wake-.Lwake0b
+.Lwait1:       
+       .long   __lll_mutex_lock_wait-.Lwait1b
+.Lwake1:
+       .long   __lll_mutex_unlock_wake-.Lwake1b
+       .size   __pthread_rwlock_rdlock,.-__pthread_rwlock_rdlock
+
+       .globl  pthread_rwlock_rdlock
+pthread_rwlock_rdlock = __pthread_rwlock_rdlock
+
+       .globl  __pthread_rwlock_rdlock_internal
+__pthread_rwlock_rdlock_internal = __pthread_rwlock_rdlock