pthread_rwlock_unlock implementation on Linux/SH.
authordrepper <drepper>
Mon, 10 Feb 2003 09:20:23 +0000 (09:20 +0000)
committerdrepper <drepper>
Mon, 10 Feb 2003 09:20:23 +0000 (09:20 +0000)
nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_unlock.S [new file with mode: 0644]

diff --git a/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_unlock.S b/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_unlock.S
new file mode 100644 (file)
index 0000000..af046aa
--- /dev/null
@@ -0,0 +1,128 @@
+/* Copyright (C) 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <lowlevelrwlock.h>
+#include "lowlevel-atomic.h"
+
+#define SYS_futex              240
+#define FUTEX_WAIT             0
+#define FUTEX_WAKE             1
+
+
+       .text
+
+       .globl  __pthread_rwlock_unlock
+       .type   __pthread_rwlock_unlock,@function
+       .align  5
+__pthread_rwlock_unlock:
+       mov.l   r12, @-r15
+       mov.l   r8, @-r15
+       sts.l   pr, @-r15
+       mov     r4, r8
+
+       /* Get the lock.  */
+       mov     #1, r3
+#if MUTEX == 0
+       XADD    (r3, @r4, r2)
+#else
+       XADD    (r3, @(MUTEX,r4), r2)
+#endif
+       tst     r2, r2
+       bf      1f
+2:
+       mov.l   @(WRITER,r8), r0
+       tst     r0, r0
+       bf      5f
+       mov.l   @(NR_READERS,r8), r0
+       add     #-1, r0
+       mov.l   r0, @(NR_READERS,r8)
+       tst     r0, r0
+       bf      6f
+5:
+       mov     #0, r0
+       mov.l   r0, @(WRITER,r8)
+       mov     r8, r4
+       mov.l   @(WRITERS_QUEUED,r8), r0
+       tst     r0, r0
+       bf      9f
+       mov     #-1, r6
+       shlr    r6              /* r6 = 0x7fffffff */
+       bra     0f
+        add    #READERS_WAKEUP, r4
+9:
+       mov     #1, r6
+       add     #WRITERS_WAKEUP, r4
+0:
+       mov     #FUTEX_WAKE, r5
+       mov     #SYS_futex, r3
+       extu.b  r3, r3
+       trapa   #0x14
+       SYSCALL_INST_PAD
+
+6:
+#if MUTEX == 0
+       DEC (@r8, r2)
+#else
+       DEC (@(MUTEX,r8), r2)
+#endif
+       tst     r2, r2
+       bf      3f
+4:
+       lds.l   @r15+, pr
+       mov.l   @r15+, r8
+       mov.l   @r15+, r12
+       rts
+        mov    #0, r0
+
+1:
+       mov     r8, r5
+#if MUTEX != 0
+       add     #MUTEX, r5
+#endif
+       mov     r2, r4
+       mov.l   .Lwait8, r1
+       bsrf    r1
+        nop
+.Lwait8b:
+       bra     2b
+        nop
+3:
+       mov     r8, r4
+#if MUTEX != 0
+       add     #MUTEX, r4
+#endif
+       mov.l   .Lwake8, r1
+       bsrf    r1
+        nop
+.Lwake8b:
+       bra     4b
+        nop
+
+       .align  2
+.Lwait8:       
+       .long   __lll_mutex_lock_wait-.Lwait8b
+.Lwake8:
+       .long   __lll_mutex_unlock_wake-.Lwake8b
+       .size   __pthread_rwlock_unlock,.-__pthread_rwlock_unlock
+
+       .globl  pthread_rwlock_unlock
+pthread_rwlock_unlock = __pthread_rwlock_unlock
+
+       .globl  __pthread_rwlock_unlock_internal
+__pthread_rwlock_unlock_internal = __pthread_rwlock_unlock