parser.rl

   1 #include <stdio.h>
   2 #include <string.h>
   3 #include <stdlib.h>
   4 #include <unistd.h>
   5 #include <fcntl.h>
   6 #include <ctype.h>
   7 #include <vector>
   8
   9 #include "inapt.h"
  10 #include "util.h"
  11
  12 using namespace std;
  13
  14 #define MAXDEPTH 100
  15 #define BUFSIZE 128
  16
  17 %%{
  18     machine inapt;
  19
  20     action pkgstart { ts = p; }
  21
  22     action add_list {
  23         inapt_action *tmp_action = new inapt_action;
  24         tmp_action->package = xstrndup(ts, p - ts); ts = 0;
  25         tmp_action->action = curaction;
  26         tmp_action->linenum = curline;
  27         tmp_action->filename = curfile;
  28         block_stack.back()->actions.push_back(tmp_action);
  29     }
  30
  31     action install {
  32         curaction = inapt_action::INSTALL;
  33     }
  34
  35     action remove {
  36         curaction = inapt_action::REMOVE;
  37     }
  38
  39     action newline {
  40         curline += 1;
  41     }
  42
  43     action start_block {
  44         if (top < MAXDEPTH) {
  45             inapt_block *tmp_block = new inapt_block;
  46             block_stack.push_back(tmp_block);
  47             fcall main;
  48         } else {
  49             fatal("%s: %d: Syntax Error: Nesting Too Deep at '}'", curfile, curline);
  50         }
  51     }
  52
  53     action end_block {
  54         if (top) {
  55             fret;
  56         } else {
  57             fatal("%s: %d: Syntax Error: Unexpected '}'", curfile, curline);
  58         }
  59     }
  60
  61     action start_conditional {
  62         inapt_conditional *cond = new inapt_conditional;
  63         cond->condition = xstrndup(ts, p - ts); ts = 0;
  64         conditional_stack.push_back(cond);
  65     }
  66
  67     action full_conditional {
  68         inapt_conditional *cond = conditional_stack.back(); conditional_stack.pop_back();
  69         cond->else_block = block_stack.back(); block_stack.pop_back();
  70         cond->then_block = block_stack.back(); block_stack.pop_back();
  71         block_stack.back()->children.push_back(cond);
  72     }
  73
  74     action half_conditional {
  75         inapt_conditional *cond = conditional_stack.back(); conditional_stack.pop_back();
  76         cond->else_block = NULL;
  77         cond->then_block = block_stack.back(); block_stack.pop_back();
  78         block_stack.back()->children.push_back(cond);
  79     }
  80
  81     newline = '\n' @newline;
  82     comment = '#' (any - '\n')* newline;
  83     whitespace = [\t\v\f\r ] | comment | newline;
  84     package_name = ((lower | digit) (lower | digit | '+' | '-' | '.')+) >pkgstart;
  85     package_list = ((whitespace+ package_name)+ %add_list whitespace*);
  86     cmd_install = ('install' @install package_list ';');
  87     cmd_remove = ('remove' @remove package_list ';');
  88     simple_cmd = cmd_install | cmd_remove;
  89     start_block = '{' @start_block;
  90     end_block = '}' @end_block;
  91     macro = alpha (alpha | digit | '-' | '+' | '.')*;
  92     cmd_if = 'if' whitespace+ macro >pkgstart %start_conditional whitespace* start_block whitespace*
  93              ('else' whitespace* start_block whitespace* ';' @full_conditional | ';' @half_conditional);
  94     cmd_list = (simple_cmd | cmd_if | whitespace)* end_block?;
  95     main := cmd_list;
  96 }%%
  97
  98 %% write data;
  99
 100 void badsyntax(const char *filename, int lineno, char badchar, const char *message) {
 101     if (!message) {
 102         if (badchar == '\n')
 103             message = "Unexpected newline";
 104         else if (isspace(badchar))
 105             message = "Unexpected whitespace";
 106         else
 107             message = "Syntax error";
 108     }
 109
 110     if (isprint(badchar) && !isspace(badchar))
 111         fatal("%s: %d: %s at '%c'", filename, lineno, message, badchar);
 112     else
 113         fatal("%s: %d: %s", filename, lineno, message);
 114 }
 115
 116 void parser(const char *filename, inapt_block *top_block)
 117 {
 118     static char buf[BUFSIZE];
 119     int fd;
 120     int cs, have = 0;
 121     int done = 0;
 122     int curline = 1;
 123     char *ts = 0;
 124
 125     std::vector<inapt_block *> block_stack;
 126     std::vector<inapt_conditional *> conditional_stack;
 127     block_stack.push_back(top_block);
 128
 129     int stack[MAXDEPTH];
 130     int top = 0;
 131
 132     const char *curfile = filename;
 133     enum inapt_action::action_t curaction = inapt_action::UNSET;
 134
 135     if (filename) {
 136         fd = open(filename, O_RDONLY);
 137         if (fd < 0)
 138             fatalpe("open: %s", filename);
 139     } else {
 140         curfile = "stdin";
 141         fd = 0;
 142     }
 143
 144     %% write init;
 145
 146     while (!done) {
 147         char *p = buf + have, *pe, *eof = 0;
 148         int len, space = BUFSIZE - have;
 149
 150         if (!space)
 151             badsyntax(curfile, curline, 0, "Overlength token");
 152
 153         len = read(fd, p, space);
 154         if (len < 0)
 155             fatalpe("Unable to read spec");
 156         pe = p + len;
 157
 158         if (!len) {
 159             eof = pe;
 160             done = 1;
 161         }
 162
 163         %% write exec;
 164
 165         if (cs == inapt_error)
 166             badsyntax(curfile, curline, *p, NULL);
 167
 168         have = 0;
 169
 170         if (ts) {
 171             have = pe - ts;
 172             memmove(buf, ts, have);
 173             ts = buf;
 174         }
 175     }
 176
 177     if (cs < inapt_first_final)
 178         badsyntax(curfile, curline, 0, "Unexpected EOF");
 179
 180     if (top)
 181         badsyntax(curfile, curline, 0, "Unclosed block at EOF");
 182 }