Updated from ../=mpn/gmp-1.906.7
[kopensolaris-gnu/glibc.git] / sysdeps / alpha / alphaev5 / add_n.s
1  # Alpha __mpn_add_n -- Add two limb vectors of the same length > 0 and
2  # store sum in a third limb vector.
3
4  # Copyright (C) 1995 Free Software Foundation, Inc.
5
6  # This file is part of the GNU MP Library.
7
8  # The GNU MP Library is free software; you can redistribute it and/or modify
9  # it under the terms of the GNU Library General Public License as published by
10  # the Free Software Foundation; either version 2 of the License, or (at your
11  # option) any later version.
12
13  # The GNU MP Library is distributed in the hope that it will be useful, but
14  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16  # License for more details.
17
18  # You should have received a copy of the GNU Library General Public License
19  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20  # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23  # INPUT PARAMETERS
24  # res_ptr      $16
25  # s1_ptr       $17
26  # s2_ptr       $18
27  # size         $19
28
29         .set    noreorder
30         .set    noat
31 .text
32         .align  3
33         .globl  __mpn_add_n
34         .ent    __mpn_add_n
35 __mpn_add_n:
36         .frame  $30,0,$26,0
37
38         ldq     $3,0($17)
39         ldq     $4,0($18)
40
41         subq    $19,1,$19
42         and     $19,4-1,$2      # number of limbs in first loop
43         bis     $31,$31,$0
44         beq     $2,.L0          # if multiple of 4 limbs, skip first loop
45
46         subq    $19,$2,$19
47
48 .Loop0: subq    $2,1,$2
49         ldq     $5,8($17)
50         addq    $4,$0,$4
51         ldq     $6,8($18)
52         cmpult  $4,$0,$1
53         addq    $3,$4,$4
54         cmpult  $4,$3,$0
55         stq     $4,0($16)
56         or      $0,$1,$0
57
58         addq    $17,8,$17
59         addq    $18,8,$18
60         bis     $5,$5,$3
61         bis     $6,$6,$4
62         addq    $16,8,$16
63         bne     $2,.Loop0
64
65 .L0:    beq     $19,.Lend
66
67         .align  4
68 .Loop:  subq    $19,4,$19
69         unop
70
71         ldq     $6,8($18)
72         addq    $4,$0,$0
73         ldq     $5,8($17)
74         cmpult  $0,$4,$1
75         ldq     $4,16($18)
76         addq    $3,$0,$20
77         cmpult  $20,$3,$0
78         ldq     $3,16($17)
79         or      $0,$1,$0
80         addq    $6,$0,$0
81         cmpult  $0,$6,$1
82         ldq     $6,24($18)
83         addq    $5,$0,$21
84         cmpult  $21,$5,$0
85         ldq     $5,24($17)
86         or      $0,$1,$0
87         addq    $4,$0,$0
88         cmpult  $0,$4,$1
89         ldq     $4,32($18)
90         addq    $3,$0,$22
91         cmpult  $22,$3,$0
92         ldq     $3,32($17)
93         or      $0,$1,$0
94         addq    $6,$0,$0
95         cmpult  $0,$6,$1
96         addq    $5,$0,$23
97         cmpult  $23,$5,$0
98         or      $0,$1,$0
99
100         stq     $20,0($16)
101         stq     $21,8($16)
102         stq     $22,16($16)
103         stq     $23,24($16)
104
105         addq    $17,32,$17
106         addq    $18,32,$18
107         addq    $16,32,$16
108         bne     $19,.Loop
109
110 .Lend:  addq    $4,$0,$4
111         cmpult  $4,$0,$1
112         addq    $3,$4,$4
113         cmpult  $4,$3,$0
114         stq     $4,0($16)
115         or      $0,$1,$0
116         ret     $31,($26),1
117
118         .end    __mpn_add_n