* sysdeps/mips/elf/start.S (ENTRY_POINT): Remove mips64 defines.
[kopensolaris-gnu/glibc.git] / sysdeps / mips / elf / start.S
1 /* Startup code compliant to the ELF Mips ABI.
2    Copyright (C) 1995, 1997, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <entry.h>
21
22 #ifndef ENTRY_POINT
23 #error ENTRY_POINT needs to be defined for start.S on MIPS/ELF.
24 #endif
25
26 /* This is the canonical entry point, usually the first thing in the text
27    segment.  The SVR4/Mips ABI (pages 3-31, 3-32) says that when the entry
28    point runs, most registers' values are unspecified, except for:
29
30    v0 ($2)      Contains a function pointer to be registered with `atexit'.
31                 This is how the dynamic linker arranges to have DT_FINI
32                 functions called for shared libraries that have been loaded
33                 before this code runs.
34
35    sp ($29)     The stack contains the arguments and environment:
36                 0(%esp)                 argc
37                 4(%esp)                 argv[0]
38                 ...
39                 (4*argc)(%esp)          NULL
40                 (4*(argc+1))(%esp)      envp[0]
41                 ...
42                                         NULL
43    ra ($31)     The return address register is set to zero so that programs
44                 that search backword through stack frames recognize the last
45                 stack frame.
46 */
47
48
49 /* We need to call:
50    __libc_start_main (int (*main) (int, char **, char **), int argc,
51                       char **argv, void (*init) (void), void (*fini) (void),
52                       void (*rtld_fini) (void), void *stack_end)
53 */
54 #ifdef __PIC__
55 /* A macro to (re)initialize gp. We can get the run time address of 0f in
56    ra ($31) by blezal instruction. In this early phase, we can't save gp
57    in stack and .cprestore doesn't work properly. So we set gp by using
58    this macro. */
59 #define SET_GP \
60         .set noreorder; \
61         bltzal $0,0f;   \
62         nop;            \
63 0:      .cpload $31;    \
64         .set reorder;
65 #endif
66
67         .text
68         .globl ENTRY_POINT
69 ENTRY_POINT:
70 #ifdef __PIC__
71         SET_GP
72 #endif
73         move $31, $0
74
75         la $4, main             /* main */
76         lw $5, 0($29)           /* argc */
77         addu $6, $29, 4         /* argv  */
78         /* Allocate space on the stack for seven arguments and make sure
79            the stack is aligned to double words (8 bytes).  */
80         and $29, 0xfffffff8
81         subu $29, 32
82         la $7, _init            /* init */
83         la $8, _fini
84         sw $8, 16($29)          /* fini */
85         sw $2, 20($29)          /* rtld_fini */
86         sw $29, 24($29)         /* stack_end */
87         jal __libc_start_main
88 hlt:    b hlt                   /* Crash if somehow it does return.  */
89
90 /* Define a symbol for the first piece of initialized data.  */
91         .data
92         .globl __data_start
93 __data_start:
94         .long 0
95         .weak data_start
96         data_start = __data_start