c48c0af7c8037254ea246c44adf5765f14dcac39
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / memset.S
1 /* Optimized memset implementation for PowerPC.
2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 /* __ptr_t [r3] memset (__ptr_t s [r3], int c [r4], size_t n [r5]));
23    Returns 's'.
24
25    The memset is done in three sizes: byte (8 bits), word (32 bits),
26    cache line (256 bits). There is a special case for setting cache lines
27    to 0, to take advantage of the dcbz instruction.  */
28
29 EALIGN (memset, 5, 1)
30
31 #define rTMP    r0
32 #define rRTN    r3      /* initial value of 1st argument */
33 #define rCHR    r4      /* char to set in each byte */
34 #define rLEN    r5      /* length of region to set */
35 #define rMEMP   r6      /* address at which we are storing */
36 #define rALIGN  r7      /* number of bytes we are setting now (when aligning) */
37 #define rMEMP2  r8
38
39 #define rPOS32  r7      /* constant +32 for clearing with dcbz */
40 #define rNEG64  r8      /* constant -64 for clearing with dcbz */
41 #define rNEG32  r9      /* constant -32 for clearing with dcbz */
42
43 /* take care of case for size <= 4  */
44         cmplwi  cr1, rLEN, 4
45         andi.   rALIGN, rRTN, 3
46         mr      rMEMP, rRTN
47         ble-    cr1, L(small)
48 /* align to word boundary  */
49         cmplwi  cr5, rLEN, 31
50         rlwimi  rCHR, rCHR, 8, 16, 23
51         beq+    L(aligned)      /* 8th instruction from .align */
52         mtcrf   0x01, rRTN
53         subfic  rALIGN, rALIGN, 4
54         add     rMEMP, rMEMP, rALIGN
55         sub     rLEN, rLEN, rALIGN
56         bf+     31, L(g0)
57         stb     rCHR, 0(rRTN)
58         bt      30, L(aligned)
59 L(g0):  sth     rCHR, -2(rMEMP) /* 16th instruction from .align */
60 /* take care of case for size < 31 */
61 L(aligned):
62         mtcrf   0x01, rLEN
63         rlwimi  rCHR, rCHR, 16, 0, 15
64         ble     cr5, L(medium)
65 /* align to cache line boundary...  */
66         andi.   rALIGN, rMEMP, 0x1C
67         subfic  rALIGN, rALIGN, 0x20
68         beq     L(caligned)
69         mtcrf   0x01, rALIGN
70         add     rMEMP, rMEMP, rALIGN
71         sub     rLEN, rLEN, rALIGN
72         cmplwi  cr1, rALIGN, 0x10
73         mr      rMEMP2, rMEMP
74         bf      28, L(a1)
75         stw     rCHR, -4(rMEMP2)
76         stwu    rCHR, -8(rMEMP2)
77 L(a1):  blt     cr1, L(a2)
78         stw     rCHR, -4(rMEMP2) /* 32nd instruction from .align */
79         stw     rCHR, -8(rMEMP2)
80         stw     rCHR, -12(rMEMP2)
81         stwu    rCHR, -16(rMEMP2)
82 L(a2):  bf      29, L(caligned)
83         stw     rCHR, -4(rMEMP2)
84 /* now aligned to a cache line.  */
85 L(caligned):
86         cmplwi  cr1, rCHR, 0
87         clrrwi. rALIGN, rLEN, 5
88         mtcrf   0x01, rLEN      /* 40th instruction from .align */
89         beq     cr1, L(zloopstart) /* special case for clearing memory using dcbz */
90         srwi    rTMP, rALIGN, 5
91         mtctr   rTMP
92         beq     L(medium)       /* we may not actually get to do a full line */
93         clrlwi. rLEN, rLEN, 27
94         add     rMEMP, rMEMP, rALIGN
95         li      rNEG64, -0x40
96         bdz     L(cloopdone)    /* 48th instruction from .align */
97
98 L(c3):  dcbz    rNEG64, rMEMP
99         stw     rCHR, -4(rMEMP)
100         stw     rCHR, -8(rMEMP)
101         stw     rCHR, -12(rMEMP)
102         stw     rCHR, -16(rMEMP)
103         nop                     /* let 601 fetch last 4 instructions of loop */
104         stw     rCHR, -20(rMEMP)
105         stw     rCHR, -24(rMEMP) /* 56th instruction from .align */
106         nop                     /* let 601 fetch first 8 instructions of loop */
107         stw     rCHR, -28(rMEMP)
108         stwu    rCHR, -32(rMEMP)
109         bdnz    L(c3)
110 L(cloopdone):
111         stw     rCHR, -4(rMEMP)
112         stw     rCHR, -8(rMEMP)
113         stw     rCHR, -12(rMEMP)
114         stw     rCHR, -16(rMEMP) /* 64th instruction from .align */
115         stw     rCHR, -20(rMEMP)
116         cmplwi  cr1, rLEN, 16
117         stw     rCHR, -24(rMEMP)
118         stw     rCHR, -28(rMEMP)
119         stwu    rCHR, -32(rMEMP)
120         beqlr
121         add     rMEMP, rMEMP, rALIGN
122         b       L(medium_tail2) /* 72nd instruction from .align */
123
124         .align 5
125         nop
126 /* Clear lines of memory in 128-byte chunks.  */
127 L(zloopstart):
128         clrlwi  rLEN, rLEN, 27
129         mtcrf   0x02, rALIGN
130         srwi.   rTMP, rALIGN, 7
131         mtctr   rTMP
132         li      rPOS32, 0x20
133         li      rNEG64, -0x40
134         cmplwi  cr1, rLEN, 16   /* 8 */
135         bf      26, L(z0)
136         dcbz    0, rMEMP
137         addi    rMEMP, rMEMP, 0x20
138 L(z0):  li      rNEG32, -0x20
139         bf      25, L(z1)
140         dcbz    0, rMEMP
141         dcbz    rPOS32, rMEMP
142         addi    rMEMP, rMEMP, 0x40 /* 16 */
143 L(z1):  cmplwi  cr5, rLEN, 0
144         beq     L(medium)
145 L(zloop):
146         dcbz    0, rMEMP
147         dcbz    rPOS32, rMEMP
148         addi    rMEMP, rMEMP, 0x80
149         dcbz    rNEG64, rMEMP
150         dcbz    rNEG32, rMEMP
151         bdnz    L(zloop)
152         beqlr   cr5
153         b       L(medium_tail2)
154
155         .align 5
156 L(small):
157 /* Memset of 4 bytes or less.  */
158         cmplwi  cr5, rLEN, 1
159         cmplwi  cr1, rLEN, 3
160         bltlr   cr5
161         stb     rCHR, 0(rMEMP)
162         beqlr   cr5
163         nop
164         stb     rCHR, 1(rMEMP)
165         bltlr   cr1
166         stb     rCHR, 2(rMEMP)
167         beqlr   cr1
168         nop
169         stb     rCHR, 3(rMEMP)
170         blr
171
172 /* Memset of 0-31 bytes.  */
173         .align 5
174 L(medium):
175         cmplwi  cr1, rLEN, 16
176 L(medium_tail2):
177         add     rMEMP, rMEMP, rLEN
178 L(medium_tail):
179         bt-     31, L(medium_31t)
180         bt-     30, L(medium_30t)
181 L(medium_30f):
182         bt-     29, L(medium_29t)
183 L(medium_29f):
184         bge-    cr1, L(medium_27t)
185         bflr-   28
186         stw     rCHR, -4(rMEMP) /* 8th instruction from .align */
187         stw     rCHR, -8(rMEMP)
188         blr
189
190 L(medium_31t):
191         stbu    rCHR, -1(rMEMP)
192         bf-     30, L(medium_30f)
193 L(medium_30t):
194         sthu    rCHR, -2(rMEMP)
195         bf-     29, L(medium_29f)
196 L(medium_29t):
197         stwu    rCHR, -4(rMEMP)
198         blt-    cr1, L(medium_27f) /* 16th instruction from .align */
199 L(medium_27t):
200         stw     rCHR, -4(rMEMP)
201         stw     rCHR, -8(rMEMP)
202         stw     rCHR, -12(rMEMP)
203         stwu    rCHR, -16(rMEMP)
204 L(medium_27f):
205         bflr-   28
206 L(medium_28t):
207         stw     rCHR, -4(rMEMP)
208         stw     rCHR, -8(rMEMP)
209         blr
210 END(memset)