cb95a58f2c1baefc659b01542df4d60a5cbc514d
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / setjmp.S
1 /* setjmp for PowerPC.
2    Copyright (C) 1995, 1996, 1997, 1999 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21 #define _ASM
22 #define _SETJMP_H
23 #include <bits/setjmp.h>
24
25 ENTRY (__sigsetjmp)
26         stw  r1,(JB_GPR1*4)(3)
27         mflr r0
28         stw  r2,(JB_GPR2*4)(3)
29         stw  r14,((JB_GPRS+0)*4)(3)
30         stfd fp14,((JB_FPRS+0*2)*4)(3)
31         stw  r0,(JB_LR*4)(3)
32         stw  r15,((JB_GPRS+1)*4)(3)
33         stfd fp15,((JB_FPRS+1*2)*4)(3)
34         mfcr r0
35         stw  r16,((JB_GPRS+2)*4)(3)
36         stfd fp16,((JB_FPRS+2*2)*4)(3)
37         stw  r0,(JB_CR*4)(3)
38         stw  r17,((JB_GPRS+3)*4)(3)
39         stfd fp17,((JB_FPRS+3*2)*4)(3)
40         stw  r18,((JB_GPRS+4)*4)(3)
41         stfd fp18,((JB_FPRS+4*2)*4)(3)
42         stw  r19,((JB_GPRS+5)*4)(3)
43         stfd fp19,((JB_FPRS+5*2)*4)(3)
44         stw  r20,((JB_GPRS+6)*4)(3)
45         stfd fp20,((JB_FPRS+6*2)*4)(3)
46         stw  r21,((JB_GPRS+7)*4)(3)
47         stfd fp21,((JB_FPRS+7*2)*4)(3)
48         stw  r22,((JB_GPRS+8)*4)(3)
49         stfd fp22,((JB_FPRS+8*2)*4)(3)
50         stw  r23,((JB_GPRS+9)*4)(3)
51         stfd fp23,((JB_FPRS+9*2)*4)(3)
52         stw  r24,((JB_GPRS+10)*4)(3)
53         stfd fp24,((JB_FPRS+10*2)*4)(3)
54         stw  r25,((JB_GPRS+11)*4)(3)
55         stfd fp25,((JB_FPRS+11*2)*4)(3)
56         stw  r26,((JB_GPRS+12)*4)(3)
57         stfd fp26,((JB_FPRS+12*2)*4)(3)
58         stw  r27,((JB_GPRS+13)*4)(3)
59         stfd fp27,((JB_FPRS+13*2)*4)(3)
60         stw  r28,((JB_GPRS+14)*4)(3)
61         stfd fp28,((JB_FPRS+14*2)*4)(3)
62         stw  r29,((JB_GPRS+15)*4)(3)
63         stfd fp29,((JB_FPRS+15*2)*4)(3)
64         stw  r30,((JB_GPRS+16)*4)(3)
65         stfd fp30,((JB_FPRS+16*2)*4)(3)
66         stw  r31,((JB_GPRS+17)*4)(3)
67         stfd fp31,((JB_FPRS+17*2)*4)(3)
68         b JUMPTARGET(__sigjmp_save)
69 END (__sigsetjmp)