1accdd70cb5ec5ac027efc97479dfaab76d3fb8c
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / strcmp.S
1 /* Optimized strcmp implementation for PowerPC.
2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21
22 /* See strlen.s for comments on how the end-of-string testing works.  */
23
24 /* int [r3] strcmp (const char *s1 [r3], const char *s2 [r4])  */
25
26 EALIGN (strcmp, 4, 0)
27
28 #define rTMP    r0
29 #define rRTN    r3      /* return value */
30 #define rSTR1   r3      /* first string arg */
31 #define rSTR2   r4      /* second string arg */
32 #define rWORD1  r5      /* current word in s1 */
33 #define rWORD2  r6      /* current word in s2 */
34 #define rFEFE   r7      /* constant 0xfefefeff (-0x01010101) */
35 #define r7F7F   r8      /* constant 0x7f7f7f7f */
36 #define rNEG    r9      /* ~(word in s1 | 0x7f7f7f7f) */
37 #define rBITDIF r10     /* bits that differ in s1 & s2 words */
38
39         or      rTMP, rSTR2, rSTR1
40         clrlwi. rTMP, rTMP, 30
41         lis     rFEFE, -0x101
42         bne     L(unaligned)
43
44         lwz     rWORD1, 0(rSTR1)
45         lwz     rWORD2, 0(rSTR2)
46         lis     r7F7F, 0x7f7f
47         addi    rFEFE, rFEFE, -0x101
48         addi    r7F7F, r7F7F, 0x7f7f
49         b       L(g1)
50
51 L(g0):  lwzu    rWORD1, 4(rSTR1)
52         bne     cr1, L(different)
53         lwzu    rWORD2, 4(rSTR2)
54 L(g1):  add     rTMP, rFEFE, rWORD1
55         nor     rNEG, r7F7F, rWORD1
56         and.    rTMP, rTMP, rNEG
57         cmpw    cr1, rWORD1, rWORD2
58         beq+    L(g0)
59 L(endstring):
60 /* OK. We've hit the end of the string. We need to be careful that
61    we don't compare two strings as different because of gunk beyond
62    the end of the strings...  */
63         and     rTMP, r7F7F, rWORD1
64         beq     cr1, L(equal)
65         add     rTMP, rTMP, r7F7F
66         xor.    rBITDIF, rWORD1, rWORD2
67         andc    rNEG, rNEG, rTMP
68         blt-    L(highbit)
69         cntlzw  rBITDIF, rBITDIF
70         cntlzw  rNEG, rNEG
71         addi    rNEG, rNEG, 7
72         cmpw    cr1, rNEG, rBITDIF
73         sub     rRTN, rWORD1, rWORD2
74         bgelr+  cr1
75 L(equal):
76         li      rRTN, 0
77         blr
78
79 L(different):
80         lwz     rWORD1, -4(rSTR1)
81         xor.    rBITDIF, rWORD1, rWORD2
82         sub     rRTN, rWORD1, rWORD2
83         bgelr+
84 L(highbit):
85         ori     rRTN, rWORD2, 1
86         blr
87
88
89 /* Oh well.  In this case, we just do a byte-by-byte comparison.  */
90         .align 4
91 L(unaligned):
92         lbz     rWORD1, 0(rSTR1)
93         lbz     rWORD2, 0(rSTR2)
94         b       L(u1)
95
96 L(u0):  lbzu    rWORD1, 1(rSTR1)
97         bne-    L(u4)
98         lbzu    rWORD2, 1(rSTR2)
99 L(u1):  cmpwi   cr1, rWORD1, 0
100         beq-    cr1, L(u3)
101         cmpw    rWORD1, rWORD2
102         bne-    L(u3)
103         lbzu    rWORD1, 1(rSTR1)
104         lbzu    rWORD2, 1(rSTR2)
105         cmpwi   cr1, rWORD1, 0
106         cmpw    rWORD1, rWORD2
107         bne+    cr1, L(u0)
108 L(u3):  sub     rRTN, rWORD1, rWORD2
109         blr
110 L(u4):  lbz     rWORD1, -1(rSTR1)
111         sub     rRTN, rWORD1, rWORD2
112         blr
113 END(strcmp)