* sysdeps/powerpc/bp-asm.h: New file.
[kopensolaris-gnu/glibc.git] / sysdeps / powerpc / sub_n.S
1 /* Subtract two limb vectors of equal, non-zero length for PowerPC.
2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
4
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Library General Public License as
7    published by the Free Software Foundation; either version 2 of the
8    License, or (at your option) any later version.
9
10    The GNU C Library is distributed in the hope that it will be useful,
11    but WITHOUT ANY WARRANTY; without even the implied warranty of
12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13    Library General Public License for more details.
14
15    You should have received a copy of the GNU Library General Public
16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
18    Boston, MA 02111-1307, USA.  */
19
20 #include <sysdep.h>
21 #include <bp-sym.h>
22 #include <bp-asm.h>
23
24 /* mp_limb_t mpn_sub_n (mp_ptr res_ptr, mp_srcptr s1_ptr, mp_srcptr s2_ptr,
25                         mp_size_t size)
26    Calculate s1-s2 and put result in res_ptr; return borrow, 0 or 1.  */
27
28 /* Note on optimisation: This code is optimal for the 601.  Almost every other
29    possible 2-unrolled inner loop will not be.  Also, watch out for the
30    alignment...  */
31
32 EALIGN (BP_SYM (__mpn_sub_n), 3, 1)
33
34 #if __BOUNDED_POINTERS__
35         slwi r10,r6,2           /* convert limbs to bytes */
36         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
37         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
38         CHECK_BOUNDS_BOTH_WIDE (r5, r8, r9, r10)
39 #endif
40
41 /* Set up for loop below.  */
42         mtcrf 0x01,r6
43         srwi. r7,r6,1
44         mtctr r7
45         bt    31,L(2)
46
47 /* Set the carry (clear the borrow).  */
48         subfc r0,r0,r0
49 /* Adjust pointers for loop.  */
50         addi  r3,r3,-4
51         addi  r4,r4,-4
52         addi  r5,r5,-4
53         b     L(0)
54
55 L(2):   lwz   r7,0(r5)
56         lwz   r6,0(r4)
57         subfc r6,r7,r6
58         stw   r6,0(r3)
59         beq   L(1)
60
61 /* Align start of loop to an odd word boundary to guarantee that the
62    last two words can be fetched in one access (for 601).  This turns
63    out to be important.  */
64 L(0):
65         lwz   r9,4(r4)
66         lwz   r8,4(r5)
67         lwzu  r6,8(r4)
68         lwzu  r7,8(r5)
69         subfe r8,r8,r9
70         stw   r8,4(r3)
71         subfe r6,r7,r6
72         stwu  r6,8(r3)
73         bdnz  L(0)
74 /* Return the borrow. */
75 L(1):   subfe r3,r3,r3
76         neg   r3,r3
77         blr
78 END (BP_SYM (__mpn_sub_n))