38bc7bbac821ed7c2f414453fac526a781c0ab94
[kopensolaris-gnu/glibc.git] / sysdeps / sparc / __longjmp.S
1 /* Copyright (C) 1991, 1993, 1996 Free Software Foundation, Inc.
2 This file is part of the GNU C Library.
3
4 The GNU C Library is free software; you can redistribute it and/or
5 modify it under the terms of the GNU Library General Public License as
6 published by the Free Software Foundation; either version 2 of the
7 License, or (at your option) any later version.
8
9 The GNU C Library is distributed in the hope that it will be useful,
10 but WITHOUT ANY WARRANTY; without even the implied warranty of
11 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
12 Library General Public License for more details.
13
14 You should have received a copy of the GNU Library General Public
15 License along with the GNU C Library; see the file COPYING.LIB.  If
16 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
17 Cambridge, MA 02139, USA.  */
18
19 #include <sysdep.h>
20
21 #include <jmp_buf.h>
22 #define ENV(reg) [%g1 + (reg * 4)]
23
24 ENTRY (__longjmp)
25         /* Store our arguments in global registers so we can still
26            use them while unwinding frames and their register windows.  */
27         mov %o0, %g1            /* ENV in %g1 */
28         orcc %o1, %g0, %g6      /* VAL in %g6 */
29         be,a 0f                 /* Branch if zero; else skip delay slot.  */
30          mov 1, %g6             /* Delay slot only hit if zero: VAL = 1.  */
31 0:
32
33         /* Cache target FP in register %g7.  */
34         ld ENV (JB_FP), %g7
35
36         /* Now we will loop, unwinding the register windows up the stack
37            until the restored %fp value matches the target value in %g7.  */
38
39 loop:   cmp %fp, %g7            /* Have we reached the target frame? */
40         bl,a loop               /* Loop while current fp is below target.  */
41          restore                /* Unwind register window in delay slot.  */
42         be,a found              /* Better have hit it exactly.  */
43          ld ENV (JB_SP), %o0    /* Delay slot: extract target SP.  */
44
45 bogus:  /* Get here only if the jmp_buf or stack is clobbered.  */
46         call C_SYMBOL_NAME (abort)
47         nop
48         unimp 0
49
50 found:  /* We have unwound register windows so %fp matches the target.  */
51         cmp %o0, %sp            /* Check jmp_buf SP vs register window.  */
52         bge,a sp_ok             /* Saved must not be deeper than register.  */
53          mov %o0, %sp           /* OK, install new SP.  */
54         b,a bogus               /* Bogus, we lose.  */
55
56 sp_ok:  ld ENV (JB_PC), %o0     /* Extract target return PC.  */
57         jmp %o0 + 8             /* Return there.  */
58          mov %g6, %o0           /* Delay slot: set return value.  */