Updated from /src/gmp-1.937
[kopensolaris-gnu/glibc.git] / sysdeps / sparc / sparc64 / add_n.s
1 ! SPARC v9 __mpn_add_n -- Add two limb vectors of the same length > 0 and store
2 ! sum in a third limb vector.
3
4 ! Copyright (C) 1995, 1996 Free Software Foundation, Inc.
5
6 ! This file is part of the GNU MP Library.
7
8 ! The GNU MP Library is free software; you can redistribute it and/or modify
9 ! it under the terms of the GNU Library General Public License as published by
10 ! the Free Software Foundation; either version 2 of the License, or (at your
11 ! option) any later version.
12
13 ! The GNU MP Library is distributed in the hope that it will be useful, but
14 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16 ! License for more details.
17
18 ! You should have received a copy of the GNU Library General Public License
19 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 ! the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23 ! INPUT PARAMETERS
24 ! res_ptr       %o0
25 ! s1_ptr        %o1
26 ! s2_ptr        %o2
27 ! size          %o3
28
29 .section        ".text"
30         .align 4
31         .global __mpn_add_n
32         .type    __mpn_add_n,#function
33         .proc   04
34 __mpn_add_n:
35         sub %g0,%o3,%g3
36         sllx %o3,3,%g1
37         add %o1,%g1,%o1                 ! make s1_ptr point at end
38         add %o2,%g1,%o2                 ! make s2_ptr point at end
39         add %o0,%g1,%o0                 ! make res_ptr point at end
40         mov 0,%o4                       ! clear carry variable
41         sllx %g3,3,%o5                  ! compute initial address index
42
43 .Loop:  ldx [%o2+%o5],%g1               ! load s2 limb
44         add %g3,1,%g3                   ! increment loop count
45         ldx [%o1+%o5],%g2               ! load s1 limb
46         addcc %g1,%o4,%g1               ! add s2 limb and carry variable
47         movcc %xcc,0,%o4                ! if carry-out, o4 was 1; clear it
48         addcc %g1,%g2,%g1               ! add s1 limb to sum
49         stx %g1,[%o0+%o5]               ! store result
50         add %o5,8,%o5                   ! increment address index
51         brnz,pt %g3,.Loop
52         movcs %xcc,1,%o4                ! if s1 add gave carry, record it
53
54         retl
55         mov %o4,%o0
56 .LLfe1:
57         .size    __mpn_add_n,.LLfe1-__mpn_add_n