Updated from /src/gmp-1.937
[kopensolaris-gnu/glibc.git] / sysdeps / sparc / sparc64 / addmul_1.s
1 ! SPARC v9 __mpn_addmul_1 -- Multiply a limb vector with a single limb and
2 ! add the product to a second limb vector.
3
4 ! Copyright (C) 1996 Free Software Foundation, Inc.
5
6 ! This file is part of the GNU MP Library.
7
8 ! The GNU MP Library is free software; you can redistribute it and/or modify
9 ! it under the terms of the GNU Library General Public License as published by
10 ! the Free Software Foundation; either version 2 of the License, or (at your
11 ! option) any later version.
12
13 ! The GNU MP Library is distributed in the hope that it will be useful, but
14 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
16 ! License for more details.
17
18 ! You should have received a copy of the GNU Library General Public License
19 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
20 ! the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
21
22
23 ! INPUT PARAMETERS
24 ! res_ptr       o0
25 ! s1_ptr        o1
26 ! size          o2
27 ! s2_limb       o3
28
29 .section        ".text"
30         .align 4
31         .global __mpn_addmul_1
32         .type    __mpn_addmul_1,#function
33         .proc   016
34 __mpn_addmul_1:
35         !#PROLOGUE#     0
36         save    %sp,-160,%sp
37         !#PROLOGUE#     1
38         sub     %g0,%i2,%o7
39         sllx    %o7,3,%g5
40         sub     %i1,%g5,%o3
41         sub     %i0,%g5,%o4
42         mov     0,%o0                   ! zero cy_limb
43
44         srl     %i3,0,%o1               ! extract low 32 bits of s2_limb
45         srlx    %i3,32,%i3              ! extract high 32 bits of s2_limb
46         mov     1,%o2
47         sllx    %o2,32,%o2              ! o2 = 0x100000000
48
49         !   hi   !
50              !  mid-1 !
51              !  mid-2 !
52                  !   lo   !
53 .Loop:
54         sllx    %o7,3,%g1
55         ldx     [%o3+%g1],%g5
56         srl     %g5,0,%i0               ! zero hi bits
57         srlx    %g5,32,%g5
58         mulx    %o1,%i0,%i4             ! lo product
59         mulx    %i3,%i0,%i1             ! mid-1 product
60         mulx    %o1,%g5,%l2             ! mid-2 product
61         mulx    %i3,%g5,%i5             ! hi product
62         srlx    %i4,32,%i0              ! extract high 32 bits of lo product...
63         add     %i1,%i0,%i1             ! ...and add it to the mid-1 product
64         addcc   %i1,%l2,%i1             ! add mid products
65         mov     0,%l0                   ! we need the carry from that add...
66         movcs   %xcc,%o2,%l0            ! ...compute it and...
67         add     %i5,%l0,%i5             ! ...add to bit 32 of the hi product
68         sllx    %i1,32,%i0              ! align low bits of mid product
69         srl     %i4,0,%g5               ! zero high 32 bits of lo product
70         add     %i0,%g5,%i0             ! combine into low 64 bits of result
71         srlx    %i1,32,%i1              ! extract high bits of mid product...
72         add     %i5,%i1,%i1             ! ...and add them to the high result
73         addcc   %i0,%o0,%i0             ! add cy_limb to low 64 bits of result
74         mov     0,%g5
75         movcs   %xcc,1,%g5
76         add     %o7,1,%o7
77         ldx     [%o4+%g1],%l1
78         addcc   %l1,%i0,%i0
79         movcs   %xcc,1,%g5
80         stx     %i0,[%o4+%g1]
81         brnz    %o7,.Loop
82         add     %i1,%g5,%o0             ! compute new cy_limb
83
84         mov     %o0,%i0
85         ret
86         restore
87 .LLfe1:
88         .size  __mpn_addmul_1,.LLfe1-__mpn_addmul_1