update from main archive 961206
[kopensolaris-gnu/glibc.git] / sysdeps / unix / sysv / linux / configure.in
1 sinclude(./aclocal.m4)dnl Autoconf lossage
2 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
3 # Local configure fragment for sysdeps/unix/sysv/linux.
4
5 # On Linux, the default is to use libio instead of stdio.
6 test $stdio = default && stdio=libio
7
8 # Don't bother trying to generate any glue code to be compatible with the
9 # existing system library, because we are the only system library.
10 inhibit_glue=yes
11
12 define([LIBC_LINUX_VERSION],[2.0.10])dnl
13 define([libc_cv_linuxVER], [libc_cv_linux]patsubst(LIBC_LINUX_VERSION,[\.]))dnl
14 AC_CACHE_CHECK(installed Linux kernel header files, libc_cv_linuxVER, [dnl
15 AC_TRY_COMPILE([#include <linux/version.h>],
16 [#if LINUX_VERSION_CODE < ]dnl
17 patsubst(LIBC_LINUX_VERSION,[^\([^.]*\)\.\([^.]*\)\.\([^.]*\)$],dnl
18 [ (\1 *65536+ \2 *256+ \3) /* \1.\2.\3 */])[
19 eat flaming death
20 #endif],
21                libc_cv_linuxVER='LIBC_LINUX_VERSION or later',
22                libc_cv_linuxVER='TOO OLD!')])
23 if test "$libc_cv_linuxVER" != 'LIBC_LINUX_VERSION or later'; then
24   AC_MSG_ERROR([GNU libc requires kernel header files from
25 Linux LIBC_LINUX_VERSION or later to be installed before configuring.
26 The kernel header files are found usually in /usr/include/asm and
27 /usr/include/linux; make sure these directories use files from
28 Linux LIBC_LINUX_VERSION or later.  This check uses <linux/version.h>, so
29 make sure that file was built correctly when installing the kernel header
30 files.])
31 fi
32
33 # The Linux filesystem standard prescribes where to place "essential"
34 # files.  I.e., when the installation prefix is "/usr" we have to place
35 # shared library objects and the configuation files on the root partition
36 # in /lib and /etc.
37 if test "$prefix" = "/usr"; then
38   libc_cv_slibdir="/lib"
39   libc_cv_sysconfdir="/etc"
40 fi
41
42 # Under Linux the LinuxThreads and crypt add-on should be available.
43 case $add_ons in
44   # Both are available.  Good.
45   *linuxthreads*des-crypt* | *des-crypt*linuxthreads*)
46     message=
47     ;;
48   *linuxthreads*)
49     message="\
50 *** WARNING:
51 *** Are you sure you do not want to use the \`crypt' add-on?"
52     ;;
53   *des-crypt*)
54     message="\
55 *** WARNING:
56 *** Are you sure you do not want to use the \`LinuxThread' add-on?"
57     ;;
58   *)
59     message="\
60 *** WARNING: Are you sure you do not want to use the \`LinuxThreads'
61 *** and \`crypt' add-ons?"
62     ;;
63 esac
64
65 if test "$message"; then
66   if test $enable_sanity = yes; then
67     echo "\
68 *** You should not compile the GNU libc without the \`LinuxThreads' and
69 *** \`crypt' add-on.  Not using them risks to be incompatible with the
70 *** libraries of other systems.  Consider getting the add-ons and restart
71 *** the configuration.
72 *** If you really mean to avoid those add-ons run configure again, now
73 *** using the extra parameter \`--disable-sanity-checks'."
74     exit 1
75   else
76     echo "$message"
77   fi
78 fi